before insert Trigger to verify if email already exists, if exists addError (CleanUP)

Question

I have created a trigger and am hopping for suggestions to clean up the trigger, making it more performant.

The reason for this trigger is: The companies' website has a PHP insert, creating Contacts in Salesforce. However, it is possible that the contact already exists in Salesforce. (The current PHP module does not allow for external ids). My solution is to throw a specific error if the Contact email already exists. The error will contain the existing Contact ID.

To throw this error I think a trigger is the best option, and this way a 'duplicate' Contact will not be created and I will be able to send the existing Contact's Id through the error.

The trigger is as follows:

    trigger trig_Contact_webToContact on Contact (before insert) 
{
    //Defining Variables    
    String errorMsg = 'The email already exists on another Contact ';
    List<String>newEmail = new List<String>();
    List<Id>newID = new List<String>();

    List<Contact> newContacts = [SELECT id, email FROM Contact WHERE ID IN: Trigger.new];

    for(Contact newContact:newContacts) //put emails and Ids in a list for use in SELECT   
    {
            newEmail.add(newContact.email);
            newID.add(newContact.Id);
    }   

    //List of Contacts that have the same email as inserted
    List<Contact> existingContacts = [SELECT id, email FROM Contact WHERE email IN: newEmail AND id NOT IN: newID]; 

    if(existingContacts.size() > 0)
    {
        for(Contact ContactError:existingContacts)
        {
            for(Contact insertedContacts:newContacts)
            {
                if(ContactError.Email == insertedContacts.Email)
                {
                    errorMsg += ContactError.Id;
                    insertedContacts.addError(errorMsg);
                    break;
                }
            }
        }
    }      
}//TRIGGER TRIG_CONTACT_WEBTOCONTACT

This trigger seems like it should work perfectly, but I feel I am repeating a few unnecessary steps. Any help on cleaning it up would be greatly appreciated.

Answer 1

I believe this should do the job (not tested it, though):

trigger trig_Contact_webToContact on Contact (before insert) 
{
  final String errMsg = 'The email already exists on another Contact: ';
  Set< String > emailSet = new Set< String >();
  for( Contact c : Trigger.new ) emailSet.add( c.Email );

  Map< String, Id > duplicateContactMap = new Map< String, Id >();

  for( Contact c : [select Id, Email from Contact where Email = :emailSet] )
    duplicateContactMap.put( c.Email, c.Id );

  for( Contact c : Trigger.new ){
    Id duplicateContactId = duplicateContactMap.get( c.Email );
    if( duplicateContactId != null )
      c.addError( errMsg + duplicateContactId );
  }
}

Answer 2

Just to offer an alternative: you don't need code for this. "Less is more"; less apex code to maintain, less unit tests to write, faster deployments, cleaner debug logs, less query rows wasted, faster execution...

1. Make a new field on Contact (type: Email, Unique: selected, External Id: if you feel like it). I'd go with "unique case insensitive" but it's your call.
2. Make a new workflow rule
   • running: every time it's changed or edited
   • condition: ISNEW() || ISCHANGED(Email)
   • value: Email
   • remember to activate
3. Run a data fix to populate it for all existing records. update [SELECT Id FROM Contact WHERE Email != null AND Unique_Email__c = null LIMIT 10000]; couple times should be ok.
4. You're done.

Answer 3

I'm going to take a gamble here that you have access to the source of the PHP SOAP client.

Can you find this line:

$results = $client->insert($contacts)

and replace with:

$results = $client->upsert('Email', $contacts)

or look deeper into the SOAP implementation to do that?