How to query all user with salesforce license?

Question

I want query the list of user with salesforce license

List<user> user11=[SELECT name from user limit 5000];

Answer 1

Didn't find how to do it in a single query, but this gives all users with a Salesforce user licence type. Important to know is that you have to query this through the profile.

Map<Id,Profile> profileIds = new Map<id,profile>([SELECT Id,UserLicenseId FROM Profile where UserLicenseId  in (SELECT Id FROM UserLicense where name ='Salesforce')]);

List<user> standardProfileUsers = [select id from user where profileId in:profileIds.Keyset()];

Update: Peter's answer is better: He shows that you can infact get these results in a single query, which is prefered for performance and cleaner in code.

Answer 2

Take a look at the UserLicense object documentation. There is a field called LicenseDefinitionKey that uniquely identifies a particular user license and the documentation lists all possible values. From the documentation:

A string that uniquely identifies a particular user license. Label is License Def. ID. Values are:

And one of the values:

SFDC: corresponds to the Full CRM user license

If what you want is the Users with the Full CRM license than the following query can get them:

List<User> usersWithSfdcLicense = [
    Select Id, Name, Profile.UserLicense.LicenseDefinitionKey 
    From User 
    Where Profile.UserLicense.LicenseDefinitionKey = 'SFDC'
];

If what you want is the Users with a License Name of Salesforce than the following query can get them:

List<User> usersWithSalesforceLicense = [
    Select Id, Name, Profile.UserLicense.Name 
    From User 
    Where Profile.UserLicense.Name = 'Salesforce'
];

Those two queries return the same Users in my org. I suppose it's possible that the UserLicense.Name field could be changed at some point by Salesforce to be something else for the Full CRM License, whereas the UserLicense.LicenseDefinitionKey field is documented as the way to identify a User License.

Answer 3

Although I have used Peter's answer in the past, I stumbled across the following which was a bit simpler:

SELECT id, Name FROM User WHERE usertype IN ('Standard')

This does however include Salesforce Platform license users (but not chatter free). See this link for the other options.

https://developer.salesforce.com/docs/atlas.en-us.object_reference.meta/object_reference/sforce_api_objects_user.htm

This fit my use case perfectly as I needed to include all users with a Salesforce license, which included those with Salesforce portal licenses in my situation.

Please note that the question here is "How to query all users with a salesforce license" - but which types of licenses is not specified - so I believe this answer is valid.

Answer 4

From the Dev console (query editor):

Select Id, Name, IsActive, Profile.UserLicense.Name 
From User 
Where Profile.UserLicense.Name = 'Salesforce' 
  AND IsActive=True

Answer 5

    map<id, id> profileIdVSuserId = new map<id, id>();
    for(User u : [SELECT ProfileId, id FROM User]){
        profileIdVSuserId.put(u.ProfileId, u.Id);
    }
    
    map<id, string> userLicIdVSuserLicName = new map<id, string>();
    for(UserLicense ul : [SELECT id, Name FROM UserLicense]){
        userLicIdVSuserLicName.put(ul.Id, ul.Name);
    }
    
    map<id, string> userIdVSuserLicName = new map<id, string>();
    for(Profile p1 : [SELECT id, UserLicenseId FROM Profile]){
        if(profileIdVSuserId.containsKey(p1.id) && userLicIdVSuserLicName.containsKey(p1.UserLicenseId)){
           userIdVSuserLicName.put(profileIdVSuserId.get(p1.id), userLicIdVSuserLicName.get(p1.UserLicenseId)); 
        }
    }
    
    system.debug('userIdVSuserLicName ===> ' + userIdVSuserLicName);

Answer 6

Map<Id,Profile> usermap = new Map<id,profile>([SELECT Id,UserLicenseId FROM Profile where name ='Salesforce']);

List<user> standardProfileUsers = [select id from user where profileId in:usermap.Keyset()];