How do I create Test Data for an Org. Wide Email Address?

Question

I need to create an Org. Wide Email address for my Test Class, and I can't seem to find documentation for this. One forum led me to believe it wasn't possible, but it wasn't clear if I was understanding it correctly. Advice?

Answer 1

You can't set up an OrgWideEmailAddress. Attempting to do so gives this error:

DML operation Insert not allowed on OrgWideEmailAddress

Fortunately, you can see them perfectly fine without SeeAllData=true. I even took the time to verify it with a simple unit test:

// This class is in version 43.0, SeeAllData=false by default
@isTest class q224877 {
    @isTest static void test() {
        OrgWideEmailAddress[] addresses = [SELECT Id FROM OrgWideEmailAddress LIMIT 1];
        System.assertEquals(1, addresses.size());
    }
}

This test, of course, passes. Typically speaking, when you're not sure if something applies to your scenario, write a unit test. Doing so saves you the trouble of trying to figure out something like this and waiting for an answer. This test took me about a minute to type up.

Answer 2

To add on to @sfdcfox's answer it may be a good idea to setup a unit test to email a specifc Organziation-wide-Address to confirm 1.) it does exist 2.) It has been verified by the given email address. Maybe something like this?:

    OrgWideEmailAddress specificOrgWideEmailAddress = [SELECT Id, Address FROM OrgWideEmailAddress WHERE DisplayName = 'Display Name of Specific Org Wide address'];
    EmailTemplate emailTemplate = [SELECT Id FROM EmailTemplate WHERE DeveloperName = 'Test_Template'];

    List<Messaging.SingleEmailMessage> emailMessagesToSend = new List<Messaging.SingleEmailMessage>();

    Contact testContact = TestUtility.buildTestContact(<testcontactinfo>);
    insert testContact;
    Id contactId = testContact.Id;

    Messaging.SingleEmailMessage email = new Messaging.SingleEmailMessage();
    email.setOrgWideEmailAddressId(specificOrgWideEmailAddress.Id);
    email.setTemplateID(emailTemplate.Id);
    email.setTargetObjectId(contactId);
    emailMessagesToSend.add(email);

    Test.startTest();
        List<Messaging.SendEmailResult> results = Messaging.sendEmail(emailMessagesToSend ,false);
    Test.stopTest();

    Boolean emailsSentSuccessfully = results[0].isSuccess();
    System.assert(emailsSentSuccessfully , 'Email failure occurred. Confirm the Organization-Wide-Address is setup and VERIFIED for Specific Org Wide address given');