Can the exact type of an Apex list be checked to choose between upsert and insert/update?

Question

I have a utility method that that works on lists of SObjects that are normally of one type:

private void oneType() {
    Contact[] contacts = new Contact[] {};
    contacts.add(new Contact(...));
    contacts.add(new Contact(...));
    upsertUtility(contacts);
}

but occasionally I want to use the method with lists of mixed SObject type:

private void mixedType() {
    SObject[] mixed = new SObject[] {};
    mixed.add(new Contact(...));
    mixed.add(new Account(...));
    upsertUtility(mixed);
}

For the second mixed case this error occurs:

DML on generic List only allowed for insert, update or delete

because of a known issue in the platform.

So I'm wondering if it is possible to detect the unsupported case for the rare occasions it comes up and use upsert for the common case. So the question is can the type of the list be detected i.e. what code could replace the ??? in this code:

private void upsertUtility(SObject[] sobs) {
    if (???) insertUpdate(sobs);
    else upsert sobs;
}

private void insertUpdate(SObject[] sobs) {
    SObject[] updates = new SObject[] {};
    SObject[] inserts = new SObject[] {};
    for (SObject sob : sobs) {
        if (sob.Id != null) updates.add(sob);
        else inserts.add(sob);
    }
    update updates;
    insert inserts;
}

Concrete lists of SObject types are subclasses of lists of SObject so instanceof doesn't help and there is no way I can see to get the type of a list. But I may be missing something.

Answer 1

You can't use upsert if the list is generic, even if it only contains one type of records. Basically, you can use getSObjectType(), and if it's null, you can't upsert:

if(sobs.getSObjectType() == null) {
   doInsertUpdate(sobs);
} else {
   Database.upsert(sobs);
}

Answer 2

As I have mentioned in comment you can pass a second parameter and based on that call your method.

Or in your generic method you can take help from sObject describe to decide if you can use upsert or not.

List<Account> accList = new List<Account>();
accList.add(new Account());
accList.add(new Account());
Set<Schema.sObjectType> sObjectType = new Set<Schema.sObjectType>();
for(Account acc : accList){
    sObjectType.add(acc.getSObjectType());
}
system.debug(sObjectType.size() );

in first use case if you check size it will return 1. Now we check the case of generic list. You can also use break to reduce the total number of iteration if you have found multiple records.

List<sObject> sObList = new List<sObject>();
sObList.add(new Account());
sObList.add(new Contact());
Set<Schema.sObjectType> sObjectType = new Set<Schema.sObjectType>();
for(sObject acc : sObList){
    sObjectType.add(acc.getSObjectType());
}
system.debug(sObjectType.size() );

Now you can check size of this set and can call different methods.

if (sObjectType.size() > 1) insertUpdate(sobs);
    else upsert sobs;