Remove {} from list to use it on SOQL string in Apex

Question

I am using a list in my soql, the list is formed with different names of countries from set of seperate records. The list(name - countryList) is of format.

    List<ABC__c> rlList = ABC__c.getall().values();
    Set<String> countryList = new Set<String>(); 
    for (ABC__c pr : rlList){     
        String countrywithquotes = '\''+ pr.Country__c + '\'';
        countryList.add(countrywithquotes);

    }

countryList - {'India', 'USA','UK','China','Brazil'}

Query String in Apex Code -

String qry = 'Select  Id, country__c from BDC__c where Country__c IN ('+ countryList +') '

In debug log , the SOQL query string produces a query like below -

Select  Id, Country__c  from ABC__c where Country__c  IN ({'India', 'USA','UK','China','Brazil'})

Please let me know a way to remove the extra { character so that the SOQL can be executed.

Answer 1

You can simply do:

List<ABC__c> rlList = ABC__c.getall().values();
    Set<String> countryList = new Set<String>(); 
    for (ABC__c pr : rlList){     
        if(!string.isBlank(pr.Country__c)) countryList.add(pr.Country__c);

    }

String query = 'Select Id From ABC__c Where Country__c In :countryList';

as dynamic queries allow bind variables

otherwise, as an exercise in learning String methods You can do something like this the generate the string you need when you cannot use a bind variable:

List<ABC__c> rlList = ABC__c.getall().values();
    Set<String> countryList = new Set<String>(); 
    for (ABC__c pr : rlList){     
        String countrywithquotes = '\''+ pr.Country__c + '\'';
        countryList.add(countrywithquotes);

    }

String query = 'Select Id From ABC__c Where Country__c In (' + 
        string.join(New List<String>(countryList),',') + ')';

This will concat the Countries (that already have quotes around them) with a comma

Depending on your idea of simplification and code placement you could also do this:

List<ABC__c> rlList = ABC__c.getall().values();
    Set<String> countryList = new Set<String>(); 
    for (ABC__c pr : rlList){     
        countryList.add(pr.Country__c);

    }

String query = 'Select Id From ABC__c Where Country__c In (\'' +
                 string.join(New List<String>(countryList),'\',\'') + '\')';

As an aside, not sure what you mean by the comment

My query in batch class is too big so can not be fit into a single line

As a query does not have to fit into a single line. The below is perfectly valid

[
   Select
        Id,
        Name
   From Account
]

As long as it is within the brackets. Additionally a dynamic string can be on multiple lines as well.

Answer 2

Do it in this way:

for(ABC__c abc: [Select  Id, country__c from ABC__c where Country__c IN: countryList]){
  //process abc record here
}

If you concatenate a List in a string then you will always get the {item1, item2, ...} so you should go for the variable binding.