Is it possible to send email to an arbitrary recipient using a VF Template?

Question

I suspect the answer here is "No", but I thought I'd ask anyway. Can I send an email, using a VFTemplate, to an arbitrary email address, as opposed to a Contact, User, or Lead?

I need to send a fairly complex email, which will require a VF email template. All merge fields in the template will come from the relatedTo object (case), nothing from recipient. These emails will be sent to an email-to-fax service, where the email-to-fax address is stored in a custom field on an account. When creating the email template in the UI, the options for Recipient Type are Contact, User, and Lead. And the documentation for SingleEmailMessage.setTargetObjectId() says "Required if using a template, optional otherwise".

So, do I have any option besides creating a "dummy" contact on the affected accounts to stor the email-to-fax email address?

Answer 1

No there's not - it has to be a record in the system, and it has to be a Contact/User/Lead and not a custom object. I recently found this out the hard way.

You can send emails to any address via Apex, but you can't reference VF templates directly that way. For HTML emails like this, I often use Apex and have a class which is specifically designed to create and handle the HTML for me.

Answer 2

It turns out there is a way to do this that I learned from John Conners. You can set the relatedTo as your user, and then setToAddresses/setBCCAddresses/setCCAddresses.

This causes any merge fields related to the recipient to be filled in with your user (or some dummy user/contact/lead)'s data, but if that doesn't matter for your use case this can be particularly useful - especially for sending a templated email to multiple addresses.

This only works with visualforce email templates.

Example code that will send to your user's email address, as well as example@example.org:

Id templateId = '00Xd0000000Y058';
Id someAccount = '001d000001MMNin';
Messaging.singleEmailmessage em = new Messaging.singleEmailMessage();
em.setTemplateId(templateId);
em.setTargetObjectId(UserInfo.getUserId());
em.setWhatId(someAccount);
em.setSaveAsActivity(false);
em.setToAddresses( new List<String>{ 'example@example.org' } );
Messaging.sendEmail( new List<Messaging.Email>{em} );

It comes across looking like this:

Answer 3

This is a late answer so maybe the solution was implemented sometime after the question was posted, but you can do this with the method setTreatTargetObjectAsRecipient(false) and then no email will be sent to the targetObjectId. Then you can set toAddresses to whoever you want the actual email recipient to be. They still require you to set some targetObjectId, otherwise no email will send at all, but you don't have to use it for anything.

Answer 4

I just wrote a blog posting on a semi-related topic. http://www.techplustalk.com/2013/10/custom-mail-merge.html

Essentially, my use-case was to use email addresses stored in custom object records and then merge different data into an email template. I used a custom object (Email__c) with a rich-text field to define my HTML email content (complete with "fake" merge fields) and then when constructing each message in my apex controller, I replace the "fake" merge fields with the data that I want.

        // create email for each application (each applicant) that satisfies criteria
        for (Application__c app : appList) {
            Email__c e = emails.get(0);  // get applicable "template"

            Messaging.SingleEmailMessage email = new Messaging.SingleEmailMessage();
            email.setToAddresses(new String[] { app.Email__c });  // set email address from application
            email.setSenderDisplayName('CARPOOL - TAMU');  // can set any name here
            email.setSubject(e.Subject__c);

            // 'hack' to replace the merge fields with values from custom object
            String body = e.Body__c.replace('{!app.name}', app.First_Name__c);

            email.setHtmlBody(body);  // rich text field is actually html content 

            // add email to emailList -- this list will hold all the emails to be sent
            emailList.add(email);
        }

        // send all individual emails using one sendEmail call
        List<Messaging.SendEmailResult> results = Messaging.sendEmail(emailList);