sObject.get(fieldname) detects changes from null to blank?

Question

I was writing a utility class which can give the names of the fields that changed during an update trigger (I have a specific set of fields that i want to track, not all fields). My code snippet is below.

My concern is, if the field is a text field, and it changes from empty string to null (or vice-versa), will this code detect it as a change? After writing my code, i tried using workbench to test it out, but its not helping. I took a record where a text field is null (got it through SOQL query). Then used Apex execute to update it to blank field (sampleRecord.fieldName__c = '';). But querying it again still shows the field as null. So i am unable to test my implementation.

public Map<Id,Set<String>> findFieldChanges(Map<Id,sObject> oldRecordsMap, Map<Id,sObject> newRecordsMap, Set<String> fieldsToBeTracked){
        Map<Id,Set<String>> recIdToFieldNamesMap = new Map<Id,Set<String>>();
        for(sObject currOldRecord : oldRecordsMap.values()){
            sObject currNewRecord = newRecordsMap.get(currOldRecord.Id);
            for(String currField : fieldsToBeTracked){
                if(currOldRecord.get(currField) != currNewRecord.get(currField)){
                    if(!recIdToFieldNamesMap.containsKey(currOldRecord.Id)){
                        recIdToFieldNamesMap.put(currOldRecord.Id, new Set<String>());
                    }
                    (recIdToFieldNamesMap.get(currOldRecord.Id)).add(currField);
                }
            }
        }
        return recIdToFieldNamesMap;
    }

The line

if(currOldRecord.get(currField) != currNewRecord.get(currField))

is what i am curious about. If it a text field, does it differentiate between null and blank?

Answer 1

The "old" value would only ever be null, never the empty string (''). These two values are not equal, so yes your code will detect the change if you set the field to the empty string instead of nulling it out.

for (MyObject__c record : trigger.new)
{
    record.TextField__c = '';
    // considered a change

    record.TextField__c = null;
    // not considered a change
}

You can also demonstrate to yourself the database stores values as null by running a unit test like the following:

static testMethod void testNullField()
{
    MyObject__c record = new MyObject__c(TextField__c='');

    Test.startTest();
        insert record;
    Test.stopTest();

    record = [SELECT TextField__c FROM MyObject__c WHERE Id = :record.Id];
    system.assertEquals(null, record.TextField__c, 'The field should be null, not blank');
}