Initial term of field expression must be a concrete SObject: List<Book__c>

Question

list<Book__c> b = [select id ,account__c,Account1__c from Book__c ];
system.debug(b);

list<account> acc = new list<account>([select id,name from account where name in :b.account__c]);
system.debug(acc);

Line: 4, Column: 83
Initial term of field expression must be a concrete SObject: List

Answer 1

In your code b is a list of objects. This would compile:

where name in :b[0].account__c

but is probably not what you want as it is only then looking at the first item.

Perhaps you want something like this is what you need:

// Get the set of accounts first
Set<String> accounts = new Set<String>();
for (Book__c b : [select account__c from Book__c where account__c != null]) {
    accounts.add(b.account__c);
}

list<account> acc = [select id,name from account where name in :accounts];
system.debug(acc);

If Book__c.Account__c is an Id, you should be matching the Id field in your second query.

Answer 2

IN used to compare any field with List of available values. From the error message it is quite clear that b.account__c is not of type list. Refer below example:

List<String> accountNames = new List<String>();
accountNames.add('Account1');
accountNames.add('Account2');

list<account> acc = new list<account>([select id,name from account where name in :accountNames]);

Answer 3

Salesforce can give some pretty unhelpful errors at time. This one isn't the clearest, but if you pause for a moment and take a good look at it, it starts to make sense.

Besides the line number, this is the most important part of the error:

must be a concrete SObject: List

So somewhere, on that line, Salesforce is expecting an SObject, but you're giving Salesforce a List.

We know it's on line 4. A SOQL query returns a List, and you're storing the result in a List, so there's no problem there (you actually don't need to use the List constructor here, or do any casting for that matter, but that's beside the point).

The only other place on line 4 that can be causing your error is this:

where name in :b.account__c

If we take a look at the lines above, b is defined as a List<Book__c>. This fits the error that you're getting. b is a List, but using dot notation to reference a field is something that needs to be done on an SObject.

Your list stored in b does contain Book__c records (Book__c is also an SObject), so to be able to access the Account__c field, you need access to one of the actual records in your list (for which you'd use [<some integer>] or .get(<some integer>)).

At the very least (and I do emphasize that this is the very least you could do), to make this work, you'd do the following

// I've omitted the rest of the query for brevity
// Notice how we use square brackets before trying to reference the field
// Apex is 0-indexed, meaning the first item in the array is at index 0 (instead of 1)
where name in :b[0].account__c];

Keith C's answer goes over better practices for accomplishing what you're looking to do.

Answer 4

list<Book__c> b = [select id,name,account__c,Account1__c from Book__c ];
system.debug(b);

list<string> s = new list<string>();
Map<Id,account> newmap = new Map<Id,account>();    

for(book__c b1 : b){
    s.add(b1.account__c);
}
system.debug(s);

list<account> acc =[select id,name from account where name IN :s];

for(account a : acc){
    newmap.put(a.id,a);

}

system.debug(newmap);

for(account a1 : acc){
       for(book__c b1 : b){ 
               if(b1.Account1__c != null){}
                    if(b1.account__c == a1.name){

                        b1.Account1__c = a1.id;
                    }
               }
        }   
}
update b; 
system.debug(b);

how to solve it by using map..

Answer 5

Where Condition Should be Return Name But It is Compared By Ids. You Should be Compare with Id's. Like [select id,name from Account where id : b.account__c];