{“error”:“unsupported_grant_type”,“error_description”:“grant type not supported”}

Question

I am getting the below error when trying to call the HTTP POST using the Apex

Http http = new Http();
HttpRequest request = new HttpRequest();
request.setEndpoint('https://ap5.salesforce.com/services/oauth2/token');
request.setMethod('POST');

request.setHeader('Content-Type', 'application/x-www-form-urlencoded');
request.setHeader('client_id','3MVG9d8..z.hDcPJZPXXXXXXXXXXXXXXXXXXX');
request.setHeader('client_secret','XXXXXXXXXXXXXXXXXX');
request.setHeader('username','XXXXXXXXXXXXXXXXXX');
request.setHeader('password','XXXXXXXXXXXXXXXXXXXXXX');
request.setHeader('grant_type','password');
request.setHeader('callbackURL','https://ap5.salesforce.com/oauthcallback.html');

request.setBody('');

HttpResponse response = http.send(request);
System.debug('Response :: '+response.getBody());

And I get the error message.

Response :: {"error":"unsupported_grant_type","error_description":"grant type not supported"}

I am able to call successfully using REST/POSTMAN client and getting the access_token.

Answer 1

Change:

request.setEndpoint('https://ap5.salesforce.com/services/oauth2/token');

to either Login or test depending on if in production or sandbox

request.setEndpoint('https://[login | test].salesforce.com/services/oauth2/token');

You also need to put the parameters in the body or as URL params and not header

request.setBody(
      'grant_type=password' + 
      '&client_id=xxxx' + 
      '&client_secret=xx' + 
      '&username=xx' + 
      '&password=xx'
);

Answer 2

I understood the concept now and thanks for sharing other links.

client_id, client_secret, username, password and grant_type should be sent in a HTTP POST body not in header.

HttpRequest req = new HttpRequest();
req.setMethod('POST');
req.setHeader('Content-Type','application/x-www-form-urlencoded');
req.setEndpoint('https://ap5.salesforce.com/services/oauth2/token');

String CLIENT_ID = 'XXXXXXXXXXXXXXXXXXXXXXXXX';
String CLIENT_SECRET = 'XXXXXXXXXXXXXXXXXXXXXXX';
String USERNAME = 'XXXXXXXXXXXXXX';
String PASSWORD = 'XXXXXXXXXXXXXX';

req.setBody('grant_type=password' + '&client_id='+CLIENT_ID + 
            '&client_secret='+CLIENT_SECRET + '&username='+USERNAME + '&password='+PASSWORD);

Http http = new Http();
HTTPResponse response = http.send(req);
System.debug('Body ' + response.getBody());
System.debug('Status ' + response.getStatus());
System.debug('Status code ' + response.getStatusCode());

Here is the output:

Answer 3

Also I found this as the simplest way.

Map<String, String> request = new Map<String, String>();
request.put('client_id','XXXXXXXXXXXX');
request.put('client_secret','XX');
request.put('username','XXX');
request.put('password','VXXXX');
request.put('grant_type','password');

String mapString = String.valueOf(request).replace(',','&')
    .replace(' ','').replace('{','').replace('}','');
System.debug('Request String '+mapString);

HttpRequest req = new HttpRequest();
req.setMethod('POST');
req.setHeader('Content-Type','application/x-www-form-urlencoded');
req.setEndpoint('https://ap5.salesforce.com/services/oauth2/token');
req.setBody(mapString);

Http http = new Http();
HTTPResponse res = http.send(req);
System.debug('Body ' + res.getBody());
System.debug('Status ' + res.getStatus());
System.debug('Status code ' + res.getStatusCode());