Changing owner overrides sharing

Question

I have a case record which I have shared with few other users manually. But when owner of the case is changed/assigned to a sales rep then all those sharing goes away and default sharing applies. Has anybody faced similar issue. Any thoughts to resolve?

Answer 1

You can persist them through the use of asynchronous code; basically, we store the state of sharing before the ownership change, then restore it afterwards.

First, we need a utility class for the future method:

public with sharing class Persistence {
    @future
    public static void persistSharing(String ShareString) {
        CaseShare[] reasons = (CaseShare[])JSON.deserialize(shareString, CaseShare[].class);
        for(CaseShare reason: reasons)
            reason.Id = null;
        Database.insert(reasons, false);
    }
}

Then, we create a trigger:

trigger CopyShare on Case (before update) {
    Set<Id> caseIds = new Set<Id>();
    for(Case record: Trigger.new)
        if(record.OwnerId != Trigger.oldMap.get(record.Id).OwnerId)
            caseIds.add(record.Id);
    Persistence.persistSharing(
        JSON.serialize(
            [SELECT Id, CaseAccessLevel, CaseId, RowCause, UserOrGroupId 
             FROM   CaseShare 
             WHERE  CaseId IN :caseIds AND 
                    RowCause = 'Manual']));

}

Note that we can only back up and restore manual shares. Other types of shares, such as from sharing rules or teams, are managed by the system.

Answer 2

Following up with SFDCFox's reponse about when the shares get deleted, I have found that the shares get deleted in between the Before and After contexts, so running the logic for recreating the shares in an After context should allow us to persist the Share records, with manual row cause, in this case.

The response that has been marked as Correct Should be updated to have the the trigger run in the After Update context for clarity.

Answer 3

This isn't the correct way to solve this. You should instead create a custom button that allows you to pick the users you want to share the record with and then insert share records for the case with a custom RowCause. (Define the RowCause) on the Case object before doing this. Once the shares are inserted using a custom rowCause, changing owner will not remove access from the shared users.

Use this for reference:

https://developer.salesforce.com/docs/atlas.en-us.apexcode.meta/apexcode/apex_bulk_sharing_creating_with_apex.htm