Update Data Extension from text response

Question

I've been working on an alternative solution to using non-keyword responses. I've been able to get that part working, however, when I try adding an AMPscript function to add or update a data extension record, I get an error thrown at me saying "There was an error processing your message".

Here's what I have set up:

Outbound message: "Hi! Would you like to receive more mobile messages? Reply Y or N

%%[
var @nxtkywrd 
set @nxtkywrd = CreateSmsConversation("85240",MOBILE_NUMBER,"Next_Keyword","MOBILECONNECT")
]%% 

Text Response message:

%%[ VAR @message
IF (Uppercase([MSG(0).NOUN(0)]) == "YES") OR (Uppercase([MSG(0).NOUN(0)]) == "Y") THEN
SET @message = "Thank you for consenting to receive messages."
ELSE
SET @message = "Ok, no more messages"
ENDIF ]%%
%%=v(@message)=%%

%%[ VAR @response
SET @response = v([MSG(0).NOUNS])
UpsertData('Data_Extension',1,'Mobile_Phone',MobileNumber,'Text_1_Response',@response)
]%%

The text response works without the UpsertData function. I've tried InsertData, UpdateData, but none seem to work. Any suggestions?

Thanks! Sean

Answer 1

You were very close Sean! I was able to get your code working as follows:

%%[
VAR @msg,@response,@inbound
SET @inbound = [MSG(0).NOUN(0)]
IF Uppercase(@inbound) == "YES" OR Uppercase(@inbound) == "Y" THEN
    SET @msg = "Thank you for consenting to receive messages."
    UpsertData('Data_Extension',1,'Mobile_Phone',Mobile_Number,'Text_1_Response',"YES")
ELSE
    SET @msg = "Ok, no more messages"
    UpsertData('Data_Extension',1,'Mobile_Phone',Mobile_Number,'Text_1_Response',"NO")
ENDIF
]%%
%%=v(@msg)=%%

Changes:

• AMPScript code for the Mobile Number of the customer is "Mobile_Number"
• You don't need v() inside an AMPScript Block to capture values.
• Changed the UpsertData function to explicit YES and NO, as it looked like you were capturing subscription flags.

Hopefully this gets you closer to achieving your goal!