Test Class for 'return null': list has no rows for assignment to sObject

Question

My Apex Class:

@AuraEnabled
public static QCT_Claim__c getClaimInfo(Id claimId){
    return [select Id, Claim_Status__c, Requested_amount__c, Amount_type__c, Treated_amount__c, Gap__c, Accept_Gap__c 
            from QCT_Claim__c
            where Id = :claimId
            limit 1];
    return null;
}

My Test Class code for the return null:

    static testMethod void getClaimInfo_Test_Null(){

    Test.startTest();
    QCT_Claim__c testClaim = QCT_NoteInfoCtrl.getClaimInfo(null);
    Test.stopTest();

    System.assertEquals(null, testClaim);
}

How to test for the return null? Doing it this way is getting me the error: list has no rows for assignment to sObject.

Answer 1

You can't hit that line since you have an unconditional return before it. If you want to return a query result you're not sure exists, assign to a list.

List<QCT_Claim__c> candidates = [/*query*/];
return candidates.isEmpty() ? null : candidates[0];

If you leave the code as is (which you shouldn't; it's broken) then an exception is your expected behavior. You will not be able to cover that last line since it's impossible to hit. But you can verify "expected" behavior:

QueryException expectedException;
try
{
    QCT_NoteInfoCtrl.getClaimInfo(null);
}
catch (QueryException q)
{
    expectedException = q;
}

system.assertNotEquals(null, expectedException,
    'Record should not be successfully queried');