REST Callout to function within Salesforce

Question

We are using HTTP callout within Salesforce logged in session but when i run the below code it is giving the below error as a response

System.HttpResponse[Status=Unauthorized, StatusCode=401]

[{"message":"Session expired or invalid","errorCode":"INVALID_SESSION_ID"}]

@future(callout=true) 
public static void doTerritoryCalloutAsync() {
    Http h = new Http();
    HttpRequest req = new HttpRequest();
    req.setEndpoint(URL.getSalesforceBaseUrl().toExternalForm() + '/services/data/v30.0/sobjects/UserTerritory');
    req.setBody('{ "TerritoryId" : record , "UserId" : userId}');
    req.setHeader('Authorization','Bearer '+UserInfo.getSessionId());
    req.setHeader('Content-Type', 'application/json');
    req.setMethod('GET');
    try{            
        system.debug('***Request Method Wala***'+req);
        HttpResponse res = h.send(req);
        if(res.getStatusCode() != 200){
            system.debug('user assigned to territory:'+ res.getBody());
        }
        else{
            system.debug('user assigned to territory:'+ res.getBody());
        }
    }
    catch(Exception e){
        system.debug('e.getMessage()');
    }
}

Answer 1

There are several things wrong with your code, but you are very much using the wrong tool for the job here. Callouts should not be necessary nor preferred.

• If you want to access specific UserTerritory records, query for them.

  List<UserTerritory> records = [
      SELECT Id FROM UserTerritory
      WHERE TerritoryId = :territoryId
      AND UserId = :userId 
  ];
  

• If you want to describe the UserTerritory object to access its schema, use describes.

  DescribeSObjectResult describe = SObjectType.UserTerritory;
  

---

Now, as for things you should fix with your code if you even want to go down this path:

• Your JSON isn't even valid. Apex isn't going to merge in local variables, if that's what you're hoping will happen there. The simplest route is probably to serialize a Map.

  request.setBody(JSON.serialize(new Map<SObjectField, Id> {
      UserTerritory.TerritoryId => territoryId, UserTerritory.UserId => userId
  }));
  

• Your catch block needs work. You should never use empty (including debug-only) catch blocks in production code, but even if you do so for testing, at least fix your debug.

  system.debug('e.getMessage()'); // not helpful
  system.debug(e.getMessage()); // better
  

Answer 2

UserInfo.getSessionId does not return a valid session Id when called asynchronously:

For Apex code that is executed asynchronously, such as @future methods, Batch Apex jobs, or scheduled Apex jobs, getSessionId returns null.

As a best practice, ensure that your code handles both cases – when a session ID is or is not available.

Instead, you need to either pass the Session ID from a synchronous context, call a login method to get a fresh Session ID, or use an OAuth flow to get a different Access Token or Refresh Token in order to be able to stay logged in in.

For a future method, the easiest way may simply be to pass in the session as a parameter:

@future(callout=true) 
public static void doTerritoryCalloutAsync(String sessionId) {

Keep in mind that this method is not foolproof; if the user explicitly logs out before you get to use the Session ID, you'll run into this error as well. If you absolutely must have it work, you'll need to arrange for something more permanent like a Refresh Token system.