How to get bulk records in rest api using rest class and by using SOQL Query and Wrapper class

Question

I am new this rest api concept in salesforce and i tried my best to get my requirement. What my requirement is

I want to return account fields like id, name, phone and industry(and etc) using wrapper class only. i tried with following class and this class is returning only one record, not all the records which meets the condition.

REST Class:

@RestResource(urlMapping='/wrapper/*')
global with sharing class campclass{
    @HttpGet
       global static Accountwrapper doget() {

            RestRequest req = RestContext.request;
            String accphone = req.requestURI.substring(req.requestURI.lastIndexOf('/')+1);
            RestResponse res = RestContext.response;

            List<Account> result = [Select Id, name,phone from account where  phone=:accphone];
            System.debug('Result:::'+result);

            Accountwrapper accWrap = new Accountwrapper();
            for(Account acc : result){
                    accWrap.accId = acc.Id;
                    accWrap.Name = acc.Name;
                    accWrap.Phone = acc.Phone;
             } 
            return accWrap;
       }
        global class Accountwrapper {
           Public Id accId;
           public String Name;
           public String Phone;

       }
}

Could any help me please, how to get bulk records by using above class.

Thanks and regards.

Answer 1

You need to return list of accounts instead of single wrapperclass instance

    @RestResource(urlMapping='/wrapper/*')
global with sharing class campclass{
    @HttpGet
       global static List<Accountwrapper> doget() {

            RestRequest req = RestContext.request;
            String accphone = req.requestURI.substring(req.requestURI.lastIndexOf('/')+1);
            RestResponse res = RestContext.response;

            List<Account> result = [Select Id, name,phone from account where  phone=:accphone];
            System.debug('Result:::'+result);

            List<Accountwrapper> accWrapList = new List<Accountwrapper>();
            for(Account acc : result){
                    Accountwrapper accWrap = new Accountwrapper();
                    accWrap.accId = acc.Id;
                    accWrap.Name = acc.Name;
                    accWrap.Phone = acc.Phone;
                    accWrapList .add(accWrap);
             } 
            return accWrapList ;
   }
        global class Accountwrapper {
           Public Id accId;
           public String Name;
           public String Phone;

       }
}

This will return all Accounts.

I am successfully able to save this as well.