Trigger doesn't iterate through all records when using Data Loader

Question

I have the following trigger for the Account object:

trigger LatestCaseBatchTrigger on Account (after update, before update) {

    public list<Issues__c> listCases = new List<Issues__c>();    
    Set<Id> AccountId = trigger.newMap.keySet();    
    public List<Account> account = [Select Id from Account where id IN :AccountId];

    List<Issues__c> casesUK = [SELECT Id, Name, RecordTypeId, CreatedDate FROM Issues__c WHERE Account__c = :AccountId AND Status__c IN ('KYC Review Complete', 'KYC Finalized', 'On-boarding Finalized') AND Client_Setup_with__c = 'BCS UK' AND RecordTypeId IN ('012b0000000kHRa', '012b0000000ULxm', '012b0000000kH4g', '012b0000000US2R') ORDER BY CreatedDate DESC NULLS LAST limit 1];     

    Set<Issues__c> setCaseToUpdate = new Set<Issues__c>();
    listCases = new List<Issues__c>();

    for(Account acc : account){             
        for(Issues__c iss : casesUK){
            iss.Latest__c = true;
            setCaseToUpdate.add(iss);
        }        
    }

    listCases.addAll(setCaseToUpdate);
    update listCases; 
}

It works fine when I update an account record manually. But when I try to make updates for all account records (through DataLoader) it doesn't run for all the accounts that I update. Please point out where I made a mistake.

Answer 1

I suggest something along these lines (I haven't tested this):

trigger LatestCaseBatchTrigger on Account (before update) {

    Issues__c[] issues = [
            SELECT Id, Name, RecordTypeId, CreatedDate, Account__c
            FROM Issues__c
            WHERE Account__c = :Trigger.newMap.keySet()
            AND Status__c IN ('KYC Review Complete', 'KYC Finalized', 'On-boarding Finalized')
            AND Client_Setup_with__c = 'BCS UK'
            AND RecordTypeId IN ('012b0000000kHRa', '012b0000000ULxm', '012b0000000kH4g', '012b0000000US2R')
            ORDER BY CreatedDate DESC NULLS LAST
            ];

    Set<Id> latestFound = new Set<Id>();
    for (Issues__c issue : issues) {
        issue.Latest__c = !latestFound.contains(issue.Account__c);
        latestFound.add(issue.Account__c);
    }

    update issues;
}

So the idea is to note when the latest issue is found for an Account by putting the Account Id in a set. (The LIMIT 1 in your query is one problem.)

If the number of issues per Account is large this will break due to governor limits and something fancier will be needed that e.g. only unsets the Latest__c field on the issues that have it set; this code unsets all but the first. There may be an aggregate query that would help in that too.

Seems a bit strange that you only want to do this when the Account changes and not when a new issue is added.