Passing Parameter Into Schedulable Class

Question

Is there a way to pass a parameter into a schedulable class execute method? We were trying to pass a string from another scheduled class into this scheduled class but it looks like we can't do that?

As quick context we have the scheduled date and time as a record in a custom object so we are trying to pass that info into our scheduled class.

global class MturkVSSchedule implements Schedulable{

    global void execute(SchedulableContext SC, **String s**){

Putting String S throws a compile error. Is there a different way that I'm missing?

Answer 1

What about passing parameters through constructor and storing them in instance variables?

public class Dummy_Schedulable_Class implements Schedulable{

    public List<String> names;
    public List<String> cronExpressions;

    public void execute(SchedulableContext SC) {
        System.debug(LoggingLevel.ERROR, names );
        System.debug(LoggingLevel.ERROR, cronExpressions );
        testScheduleClassMethod(names[0]);
    }

    public void testScheduleClassMethod(string argPass){

    }

    public Dummy_Schedulable_Class ( List<String> aNames, List<String> aCronExps) {
        if ( names == null ) {
            names = aNames;
        } else {
            names.addAll(aNames);
        }
        if ( cronExpressions == null ) {
            cronExpressions = aCronExps;
        } else {
            cronExpressions.addAll(aCronExps);
        }
    }

}

And whenever you need to pass parameters you can do the following:

System.schedule('test', '0 47 18 * * ?', new Dummy_Schedulable_Class(new String[]{'a','b'}, new String[]{'c','d'}));

Please mark this answer as accepted or vote up if you agree that it answers your question.

Answer 2

There is no way to pass information in an Apex sense.

Passing Information to Schedulable Job using a Custom Object.

You can pass information via the database, the basic steps are this...

1. Use the Id returned from the System.schedule method
2. After scheduling the job insert a record into a Custom Object (e.g. Schedule Info) that contains the information you want the job to read when it executes. Being sure to also store the job Id on the record.
3. Then in the execute method use the SchedulableContext.getTriggerId (confusing name i know) method to obtain the job Id and query the record previously written for the information needed.
4. You should consider putting in a try/finally some cleanup code to delete the record once the execute completes.

Apologies for not giving a code sample here, let me know if you need one and I can work one up.

NOTE: You may also want to consider using a List type protected Custom Setting, which has the benifit of saving DML, SOQL and is hidden from the end users.

Answer 3

I use generally use a static variable (as seen below), and pass that into a system.schedule call, but there's no reason you cant query the database to construct the string instead. I hope this helps

global class ScheduledJob implements Schedulable {

    public static String Sched = '0 00 22 * * ?';  //Every Day at 10PM 
    //I use a set schedule, you can instead query your custom object below      

    global static String scheduleThisJob() {

        object object = [Select Id, Name From Custom_Object__c];
        Sched =  ?? //use the object above to construct the chron for the scheduled job

        ScheduledJob SJ= new ScheduledJob(); 
        return System.schedule('My Scheduled Job', Sched, SJ);
    }

    global void execute(SchedulableContext sc) {

        BatchActiveMemberCheck BatchActive = new BatchActiveMemberCheck(ActiveMemberCheckUtililty.activeContactIDs());
        ID batchprocessid = Database.executeBatch(BatchActive,50);      
    }


}

Answer 4

Here's my way of passing parameters to a schedulable apex class.

This following class has a constructor that takes two parameters and sets the class attributes to hold the values passed into as the arguments and creates an instance object of the class which will contain the class attributes as well as the class methods. Here we have one method called main (note: this is an arbitrary name).

The execute method is the Schedulable interface's method which needs to be specified because we're implementing the interface and this method calls the instance object's main method which can use the passed-in arguments that have been saved into the object's attribute variables.

public with sharing class CronJob_That_Takes_Parameters implements Schedulable {
    String aString; Integer toBeCalculated;
    @testVisible Integer anInteger; // tip: use @testVisible annotation if you want to avoid hard coding values in the unit test

    public void execute(SchedulableContext ctx) {
        this.main(); // invoke the main method from this schedulabel execute method
    }

    // this is the class constructor
    public CronJob_That_Takes_Parameters(String aString, Integer anInteger) {
        this.aString = aString;
        this.anInteger = anInteger;
        this.toBeCalculated = this.anInteger * this.aString.size() /* you can also use custom settings and/or custom metadata values here */;
    }

    // put in the code for the main process
    public void main() {
        try {
            // main logic

        } catch (Exception ex) {
            // error handling
        }
    }
}

in order to schedule this class use the following code.

    // schedule the cron job
    String aString = 'String value argument', cronExp = '0 0 6 ? * MON-FRI'; // every weekday at 6am
    Integer anInteger = 10;
    CronJob_That_Takes_Parameters cronJob = new CronJob_That_Takes_Parameters(aString, anInteger);
    System.schedule('cron job name goes here!', cronExp, cronJob);