How to pass multiple value to url parameter

Question

I am creating a custom button on a custom object A. The custom object A has multiple accounts related to it. Custom object A has a lookup relation to Account.

In the button logic I am using Button or Link URL option to set the url of button. I wish to pass all the IDs of accounts which are part of custom object A. like:

https://test.salesforce.com/apex/AVisualForcePage?accid="all account id should be passed here"&scontrolCaching=1&sfdc.override=1....

I am trying to figure out how all the account id's(accid parameter) can be passed in this URL. The Javascript code in my Visualforce page has this function to parse the accid parameter:

Question: how can I pass multiple accountid values in the same parameter dynamically? Can you use a custom field on custom object A to store all the id's and set it in URL parameter?

// init method to load appropriate javascript!
            var init = function() {

                // adds custom contains method
                addContainsToString();
                // loads the tree based on JSON data
                loadTree({!jsonData});
                var key = getUrlParameter("accid");
                nodeSelection(key);


 var getUrlParameter = function getUrlParameter(sParam) {
            var sPageURL = decodeURIComponent(window.location.search.substring(1)),
                sURLVariables = sPageURL.split('&'),
                sParameterName,
                i;

            for (i = 0; i < sURLVariables.length; i++) {
                sParameterName = sURLVariables[i].split('=');

                if (sParameterName[0] === sParam) {
                    return sParameterName[1] === undefined ? true : sParameterName[1];
                }
              }
           }

Answer 1

If you want all child Account records, just pass the parent Id and query for the children in your constructor. Or you can pass in the Account Id itself and query for the siblings.

public List<Account> children { get; private set; }
public MyExtension(ApexPages.StandardController controller)
{
    // if using parent
    children = [SELECT ... FROM Account WHERE Parent__c = :controller.getId()];
}
public MyExtension(ApexPages.StandardController controller)
{
    // if using Account
    Account record = [SELECT Parent__c FROM Account WHERE Id = :controller.getId()];
    children = [SELECT ... FROM Account WHERE Parent__c = :record.Parent__c];
}

Answer 2

Adding on to what Adrian mentioned, you can try below to see the different results. If you are using a detail button on the object you'll have the id in the URL for it, so then you can query for the accounts based on that. I wouldn't look into passing the accIds into the url.

global class OjbectACtrl {

    private final ObjectA__c objectA;
    public List<Account> accounts {get; set;}

    public OjbectACtrl(ApexPages.StandardController controller) {       
        objectA = (ObjectA__c)controller.getRecord();
        accounts = [SELECT Id, Name FROM Account WHERE ObjectA__c = :controller.getId()];
    }

    @RemoteAction
    global static List<Account> getAccounts(String recordId) {
        return [SELECT Id, Name FROM Account WHERE ObjectA__c = :recordId];
    }

    // If you need more control of what gets return you can use a wrapper   
   global class AccountWrapper {

       public String accId {get; set;}
       public String accountName {get; set;}

        public AccountWrapper(String accId, String accountName) {
            this.accId = accId;
            this.accountName = accountName;
        }
    }

    @RemoteAction
    global static List<AccountWrapper> getAccountWrapper(String recordId) {
        List<AccountWrapper> aws = new List<AccountWrapper>();
        List<Account> accounts = [SELECT Id, Name FROM Account WHERE ObjectA__c = :recordId];
        for (Account a: accounts) {
            AccountWrapper aw = new AccountWrapper(a.Id, a.Name);
            aws.add(aw);
        }    
        return aws;
    }
}

Then on the VF page:

<apex:page standardController="ObjectA__c" extensions="OjbectACtrl" >

<script>
// This is a string
var accounts = '{!accounts}';
function getAccounts() {
    var recordId='{!$CurrentPage.Parameters.id}'
    Visualforce.remoting.Manager.invokeAction('OjbectACtrl.getAccounts',
        recordId,                                      
        function(result, event) {
            if (event.status) {
                console.log('Account List Result as object array');
                console.log(result);
                // This will be valid JSON
                console.log(JSON.stringify(result));
            } else {
                console.log(event.message);
            }
        }, {
        escape: true
    });                                      
}
function getAccountWrapper() {
    var recordId='{!$CurrentPage.Parameters.id}'
    Visualforce.remoting.Manager.invokeAction('OjbectACtrl.getAccountWrapper',
        recordId,                                      
        function(result, event) {
            if (event.status) {
                console.log('Account Wrapper Result as object array');
                console.log(result);
                // This will be valid JSON
                console.log(JSON.stringify(result));
            } else {
                console.log(event.message);
            }
        }, {
        escape: true
    });                                      
}
</script>
</apex:page>