Can't Insert CollaborationGroup in Test Class

Question

I've got a Trigger that will automatically add newly created Users to our companies main chatter group. It works as expected, but the test class is failing for some strange reason!

When I try to insert a new CollaborationGroup like below:

CollaborationGroup cg = new CollaborationGroup(
  Name = 'New Group',
  CollaborationType = 'Private'
);

INSERT cg;

... And query for that Id like below:

Id theChatterGroup = [SELECT Id FROM CollaborationGroup WHERE Name = 'New Group' LIMIT 1].Id;

I get the following error:

System.DmlException: Insert failed. First exception on row 0; first error: DUPLICATE_VALUE, An active or archived group with this name already exists or is being deleted. Choose a different name or try again in a few minutes.: [Name]

So I figured "okay, maybe CollaborationGroups are like profiles or something and don't need to be created in test classes?". But when I remove that insert, I get this error...

System.QueryException: List has no rows for assignment to SObject

... When I'm querying for the Id of the Chatter Group.

I feel like I'm missing something obvious here. Can anyone guide me in the right direction?

Edit The group exists in both production and I created it in the Sandbox. When we refreshed the sandbox, we didn't migrate and Chatter data.

Edit 2 I've tried checking if it exists, but still getting the same errors.

Integer cgExists = [SELECT Count() FROM CollaborationGroup WHERE Name = 'My Group'];

if (cgExists == 0) {
  CollaborationGroup cg = new CollaborationGroup(
    Name = 'My Group',
    CollaborationType = 'Private'
  );

  INSERT cg;
}

Answer 1

I ran into this same issue recently. In my case, I was trying to create multiple Chatter groups as a part of our Sandbox Refresh Script. Turns out existing CollaborationGroups are not visible during a test, but they are still evaluated for the unique group name requirement.

Using the @IsTest(SeeAllData=true) annotation for your test method will allow you to check if the group already exists; then you can either create a new group or interact with the existing group.

Class for creating Chatter groups

private static void createChatterGroups(List<String> grpNames){
    //Map existing Chatter groups that match list of group names
    Map<String, CollaborationGroup> grpMap = new Map<String, CollaborationGroup>();
    for (CollaborationGroup cg : [SELECT Name FROM CollaborationGroup WHERE Name IN :grpNames]) {
        grpMap.put(cg.Name, cg);
    }
    //Create Public Chatter groups
    List<CollaborationGroup> grps = new List<CollaborationGroup>();
    for (String grpName:grpNames) {
        //Confirm group does not already exist
        if (!grpMap.containsKey(grpName)) {
            CollaborationGroup g = new CollaborationGroup(Name=grpName, CollaborationType='Public');
            grps.add(g);
        }
    }
    insert grps;
}

Test class

@isTest(SeeAllData=true)
static void createChatterGroupTest() { 
    List<String> grpNames = new List<String> {'Group1','Group2'};

    Test.startTest();
    createChatterGroups(grpNames);
    Test.stopTest();

    //Validate that Chatter groups exist
    Map<String, CollaborationGroup> grpMap = new Map<String, CollaborationGroup>();
    for (CollaborationGroup cg : [SELECT Name FROM CollaborationGroup]) {
        grpMap.put(cg.Name, cg);
    }
    for (String grpName:grpNames) {
        system.assert(grpMap.containsKey(grpName), grpName + ' Chatter group was not created');
    }
}

Answer 2

You may want to adopt a loading strategy that will work even if called multiple times.

public static final String NEW_GROUP_NAME = 'New Group';
public static CollaborationGroup newGroupId
{
    get
    {
        if (newGroupId == null)
        {
            // first check if it's in the database
            List<CollaborationGroup> candidates = [
                SELECT Id FROM CollaborationGroup
                WHERE Name = :NEW_GROUP_NAME
            ];
            if (!candidates.isEmpty()) newGroupId = candidates[0].Id;
            else
            {
                // only create the group if it's missing
                CollaborationGroup newGroup = new CollaborationGroup(Name=NEW_GROUP_NAME);
                insert newGroup;
                newGroupId = newGroup.Id;
            }
        }
        return newGroupId;
    }
    private set;
}

Answer 3

I also ran into this. I eventually gave up on trying to make CG visible to both production and test.

Instead I created a test version of the collaboration group and put all my newly created test users in the test group. You can check Test.isRunningTest() to set the group's name to either the production or test version.

This also has the benefit of not depending on the state of any row in CollaborationGroup (seeAllData=false is the best way to write test classes in my view anyway).

---

Update -

We have a CollaborationGroup which contains all users of a specific application, named something like "All App Users".

In production Code (triggers, etc.) we use logic like this:

string nm = Test.isRunningTest() ? 'test All App Users' : 'All App Users'; CollaborationGroup cg = [SELECT Id FROM CollaborationGroup WHERE Name=:nm];

Any test classes refer only to "Test All App Users", which means the test Collaboration Group has to be created before each such test, and any users you'll be testing with need to be added to CollaborationGroupMember.

I think I read somewhere that SF purchased CollaborationGroup, ContentDocument and other chatter features from another company and they haven't integrated them so that they are consistent with the same way as other SF objects work. CollaborationGroup's behavior (is it a setup object or not?) is a good example of this issue. Another example is how ContentDocumentLink works. You can only query one document at a time (not a collection of docs).

Answer 4

I was struggling with this issue until I realized I was calling the @testSetup method twice, I forgot the method runs automatically when the tests start so I called it inside my tests.

Hope this helps.