Check the status of a scheduled batch job

Question

I have a vf page on which there is only one command button which on click calls "ExecuteBatch" method.

Method as given below :

 public void executeBatch() {
       ACPBoxInvoiceDataBatch batch = new ACPBoxInvoiceDataBatch ();
       Database.executeBatch(batch);
    }

Now I need to check the status of batch job and depending on success and failure, I need to show the message on VF page.

Answer 1

http://www.tehnrd.com/batch-apex-status-bar/

This is a nice Batch Status bar you might want to look into

---

And that i achecvied by check the AsyncApexJob.Status using the JobId from the Database.BatchableContext.

E.g.

    global void finish(Database.batchablecontext bc) {

    // Check batch status - IF COMPLETED then 
    AsyncApexJob a = [Select Id, Status, NumberOfErrors, JobItemsProcessed,
        TotalJobItems, CreatedBy.Email, ExtendedStatus
        from AsyncApexJob where Id = :bc.getJobId()];        

    if(a.Status == 'Completed') {


        // 1. Send Email (CSV created in execute method)


        Messaging.SingleEmailMessage mail = new Messaging.SingleEmailMessage();
        // Send the email to the job submitter
        String[] toAddresses = new String[] {a.CreatedBy.Email};
        mail.setToAddresses(toAddresses);
        mail.setSenderDisplayName('Batch Processing');
        mail.setSubject('x70RecordExtract  Status: ' + a.Status);
            mail.setPlainTextBody('The batch Apex job processed ' + a.TotalJobItems +
            ' batches with '+ a.NumberOfErrors + ' failures. ExtendedStatus: ' + a.ExtendedStatus);

        // Add your attachment to the email.

        Messaging.sendEmail(new Messaging.SingleEmailMessage[] { mail });


        // 2. database.executebatch(new chain_batch(),200);

    }
} 

Answer 2

Your page has to continuously poll the controller at a fixed time interval and display message on the basis of percent complete.

Sample Controller

    public class BatchRunController {
        public boolean batchProcessed;
        public BatchRunController(){
            batchProcessed = false;    
        }
        public String getMessage(){
            if(batchProcessed){
                Double itemsProcessed;
                Double totalItems ;
                for(AsyncApexJob a : [select TotalJobItems, Status, NumberOfErrors, MethodName, JobType, JobItemsProcessed, Id, 
CreatedDate, CreatedById, CompletedDate, ApexClassId, ApexClass.Name From AsyncApexJob where ApexClass.Name = 'ACPBoxInvoiceDataBatch' order by CreatedDate desc limit 1]){
                    itemsProcessed = a.JobItemsProcessed;
                    totalItems = a.TotalJobItems;
                }
                //Determine the percent complete based on the number of batches complete and set message
                if(totalItems == 0){
                    //A little check here as we don't want to divide by 0.
                    return 'Batch Job 0% Complete';
                }else{
                    return 'Batch Job ' + String.valueof(((itemsProcessed  / totalItems) * 100.0).intValue())+'% Complete.';
                }

            } else {
                return 'Batch Job not yet executed !!';
            }
        }

        public PageReference process() {
            ACPBoxInvoiceDataBatch batch = new ACPBoxInvoiceDataBatch();
            Database.executeBatch(batch);
            batchProcessed = true;
            return null;
        }

    }

Sample VF page

<apex:page controller="BatchRunController">
  <apex:form >
  <apex:pageBlock >
  <apex:actionPoller rerender="msg" interval="5"/>
    <apex:commandButton action="{!process}" value="EXECUTE" rerender="msg"/>
    <Br/><Br/>
  <apex:outputLabel value="{!Message}" id="msg" style="text-wight:bold;"/>
  </apex:pageBlock>
  </apex:form>
</apex:page>

Initial Display

Display after clicking Execute

After this display, the VF page keeps on polling and displaying appropriate percentages every 5 seconds, and it shows 100% after execution is complete. [Note - Polling will still continue]

Answer 3

You need to query on crontrigger object to get details of submitted jobs as

List<CronTrigger> listCronTrigger  = [SELECT Id, OwnerId, CronExpression 
      FROM CronTrigger WHERE CronExpression like '% MyJobName'];
  system.debug(listCronTrigger);

Answer 4

Below query can be used to get the Status of the Batch Job based on name

SELECT >APEX_CLASS_NAME<, MethodName,JobItemsProcessed,TotalJobItems, JobType, Status, NumberOfErrors, createdby.name, createddate 
FROM AsyncApexJob 
WHERE jobtype='BatchApex' AND apexclass.name=>BATCH_JOB_NAME<