Problems writing a Test class for the salesforce OpportunityTerritory2AssignmentFilter class

Question

I am trying to write a test class for OpportunityTerritory2AssignmentFilter

It implements the TerritoryMgmt.OpportunityTerritory2AssignmentFilter and is a sample class provided by salesforce. Has any one used this Class before OpportunityTerritory2AssignmentFilter ?

If anyone has worked on this before any help, references or suggestions are highly appreciaed ! :)

You can find this class here or below...

https://developer.salesforce.com/docs/atlas.en-us.apexcode.meta/apexcode/apex_interface_TerritoryMgmt_OpportunityTerritory2AssignmentFilter.htm

    /*** Apex version of the default logic.
* If opportunity's assigned account is assigned to
*  Case 1: 0 territories in active model
*            then set territory2Id =   null
*  Case 2: 1 territory in active model
*            then set territory2Id =   account's territory2Id
*  Case 3: 2 or more territories in active model
*            then set territory2Id =   account's territory2Id that is of highest priority.
*            But if multiple   territories have same highest priority, then set territory2Id = null 
*/
global class OppTerrAssignDefaultLogicFilter implements
TerritoryMgmt.OpportunityTerritory2AssignmentFilter {
     /**
     * No-arg constructor.
     */ 
     global   OppTerrAssignDefaultLogicFilter() {}

     /**
      * Get mapping of   opportunity to territory2Id. The incoming list of opportunityIds contains only those with IsExcludedFromTerritory2Filter=false.
      * If territory2Id =   null in result map, clear the opportunity.territory2Id if set.
      * If opportunity is not present in result map, its territory2Id remains intact.
      */
    global Map<Id,Id> getOpportunityTerritory2Assignments(List<Id> opportunityIds) {
        Map<Id,   Id> OppIdTerritoryIdResult = new Map<Id, Id>();

        //Get the active territory model Id
        Id   activeModelId = getActiveModelId();

        if(activeModelId   != null){
            List<Opportunity>   opportunities =
              [Select Id, AccountId, Territory2Id from Opportunity where Id   IN
              :opportunityIds];
            Set<Id>   accountIds = new Set<Id>();
            //Create   set of parent accountIds
            for(Opportunity opp:opportunities){
                if(opp.AccountId   != null){
                    accountIds.add(opp.AccountId);
                    }
                }

                Map<Id,Territory2Priority> accountMaxPriorityTerritory = 
getAccountMaxPriorityTerritory(activeModelId, accountIds);

            //for each opportunity, assign the highest priority territory if there is 
no conflict, else assign null
            for(Opportunity opp: opportunities){
               Territory2Priority tp = accountMaxPriorityTerritory.get(opp.AccountId);
               //assign highest priority
              territory if there is only 1
              if((tp   != null) && (tp.moreTerritoriesAtPriority == false) && 
(tp.territory2Id != opp.Territory2Id)){
                   OppIdTerritoryIdResult.put(opp.Id, tp.territory2Id);
               }else{
                   OppIdTerritoryIdResult.put(opp.Id,   null);
               }
            }
        }
        return   OppIdTerritoryIdResult;
    }

    /**
      * Query assigned territoryIds in active model for given accountIds
      * Create a map of accountId to max priority territory 
      */
     private Map<Id,Territory2Priority> getAccountMaxPriorityTerritory(Id
activeModelId, Set<Id> accountIds){
        Map<Id,Territory2Priority> accountMaxPriorityTerritory = new 
Map<Id,Territory2Priority>();
        for(ObjectTerritory2Association ota:[Select ObjectId, Territory2Id, 
Territory2.Territory2Type.Priority from ObjectTerritory2Association where objectId IN 
:accountIds and Territory2.Territory2ModelId = :activeModelId]){
            Territory2Priority tp = accountMaxPriorityTerritory.get(ota.ObjectId);

            if((tp   == null) || (ota.Territory2.Territory2Type.Priority > 
tp.priority)){
                //If this is the first territory examined for account or it has 
greater priority than current highest priority territory, then set this as new highest 
priority territory.
                tp = new 
Territory2Priority(ota.Territory2Id,ota.Territory2.Territory2Type.priority,false);
            }else if(ota.Territory2.Territory2Type.priority == tp.priority){
                //The priority of current highest territory is same as this, so set   
moreTerritoriesAtPriority to indicate multiple highest priority territories seen so far.
                tp.moreTerritoriesAtPriority = true;
            }

            accountMaxPriorityTerritory.put(ota.ObjectId,   tp);
        }
        return accountMaxPriorityTerritory;
    }


    /**
     * Get the Id of the Active Territory Model. 
     * If none exists, return   null;
     */
   private Id getActiveModelId() {
       List<Territory2Model>   models = [Select Id from Territory2Model where State = 'Active'];
       Id activeModelId = null;
       if(models.size()   == 1){
           activeModelId = models.get(0).Id;
       }

       return activeModelId;
   }

   /**
    * Helper class to help   capture territory2Id, its priority, and whether there are more territories with same priority assigned to the
 account
    */
   private class Territory2Priority {
       public Id territory2Id { get; set; }
       public Integer priority { get; set; }
       public   Boolean moreTerritoriesAtPriority { get; set; }

              Territory2Priority(Id territory2Id, Integer priority, Boolean moreTerritoriesAtPriority){
           this.territory2Id = territory2Id;
           this.priority = priority;
           this.moreTerritoriesAtPriority = moreTerritoriesAtPriority;
       }
   }
}}

My Test class:

   **My Test Class :**

       @istest
Private class OppTerrAssignDefaultLogicFiltertest{
Private static testmethod void oppTerrAssigntest(){

Opporunity opp =new Opporunity(name='testopporunity');
insert opp;
List<id> opplistid=new List<id>();
opplistid.add(opp.id);

Account acc =new Account(name='testaccount');
insert acc;
Set<id> acclistid=new Set<id>();
opplistid.add(acc.id);


OppTerrAssignDefaultLogicFilter CheckOppty=new OppTerrAssignDefaultLogicFilter();
Map<Id,Id> mapid=CheckOppty.getOpportunityTerritory2Assignments(opplistid);
Map<Id,Territory2Priority>MapTerritory=CheckOppty.getAccountMaxPriorityTerritory(vn897, acclistid)
Id id=CheckOppty.getActiveModelId();


OppTerrAssignDefaultLogicFilter.Territory2Priority innerclass=new OppTerrAssignDefaultLogicFilter.Territory2Priority(Vn897,9908,true);
innerclass.territory2Id;
innerclass.priority;
innerclass.moreTerritoriesAtPriority;

}
}

I'm getting the following error:

invalid type : Territory2Priority

Answer 1

Ok So the internal class of Territory2Priority ( the type) is noted as Private and you are trying to access this in a test class.

Private will make it only visible inside its class constant.

+1 salesforce here, Add @TestVisible on top of the private and you will be able to access the class from your test.

Updating the second part

In the test you are calling the class inside a map MapTerritory You need to add infront of this call where it site I.E the class name So your map should look like this

Map<Id, OppTerrAssignDefaultLogicFilter.Territory2Priority >MapTerritory=CheckOppty.getAccountMaxPriorityTerritory(vn897, acclistid)

Next you are going to get more calls saying could not find methods because they are set to be private. Make them all @TestVisible private Or public. Finial

innerclass.territory2Id;
innerclass.priority;
innerclass.moreTerritoriesAtPriority;

Needs to be checked not just called.So these become

System.assertEqual(Vn897 ,innerclass.territory2Id, 'Fail');
System.assertEqual(9908 ,innerclass.priority, 'Fail');
System.assertEqual(true ,innerclass.moreTerritoriesAtPriority, 'Fail');

Also in the Class the constructor for Territory2Priority is not visible give it ether public or @TestVisible Private

Apologies, Forgot that the class is Global, so inner class must be global. https://developer.salesforce.com/docs/atlas.en-us.apexcode.meta/apexcode/apex_classes_defining.htm

Answer 2

Since I can't found an OOTB test class for this anywhere, I just wrote one up real quick.

Requirement in OpportunityTerritory2AssignmentFilter class:

You will need to mark the inner class and its constructor @TestVisible

@testVisible
private class Territory2Priority {
    public Id territory2Id { get; set; }
    public Integer priority { get; set; }
    public Boolean moreTerritoriesAtPriority { get; set; }

    @testVisible
    Territory2Priority(Id territory2Id, Integer priority, Boolean moreTerritoriesAtPriority) {

Test Class:

@isTest
public class OpportunityTerritory2AssignmentFilterTests {


@isTest
static void unitTest() {
    Id opportunityId = [Select Id From Opportunity].Id;
    OpportunityTerritory2AssignmentFilter filter = new OpportunityTerritory2AssignmentFilter();

    Test.startTest();

    Map<Id, Id> resultMap = filter.getOpportunityTerritory2Assignments(new List<Id> {opportunityId});
    OpportunityTerritory2AssignmentFilter.Territory2Priority tp = new OpportunityTerritory2AssignmentFilter.Territory2Priority(opportunityId, 1, false);

    Test.stopTest();

    System.assertEquals(1, resultMap.size());
    System.assertEquals(tp.territory2Id, opportunityId);
    System.assertEquals(1, tp.priority);
    System.assertEquals(false, tp.moreTerritoriesAtPriority);
}

@testSetup
static void setup() {
    Account account = new Account(Name = 'testAccount');
    insert account;

    Opportunity opp = new Opportunity(
        Name = 'Opportunity',
        CloseDate = System.today().addDays(10),
        StageName = 'Prospecting',
        AccountId = account.Id
    );
    insert opp;
}
}

Hopefully this will save somebody a few minutes somewhere down the road.

Answer 3

Below is test class which have 92% coverage. but you need to add @TestVisible in apex class for each method.

@isTest Public class Test_OppTerrAssignDefaultLogicFilter {

Public static testmethod void oppTerrAssigntest(){
    
    Account account = new Account(Name = 'testAccount');
    insert account;
    
    Opportunity opp = new Opportunity(
        Name = 'Opportunitytest',
        CloseDate = System.today().addDays(10),
        StageName = 'Discovery & Qualification',
        AccountId = account.Id
    );
    insert opp;
    List<id> opplst   = new List<id>() ;
    opplst.add(opp.id);
    
    Set<Id> accountIds = new Set<Id>();
    accountIds.add(account.id);
    User usr = [Select id from User where Id = :UserInfo.getUserId()];
    
    System.RunAs(usr)
    {
        List<Territory2Type> terriType   = [SELECT id, DeveloperName from Territory2Type];
        
        Territory2Model terrModel   = new Territory2Model(DeveloperName='ModelName',Name = 'Name');
        insert terrModel;
        Territory2 objTerr =new Territory2(DeveloperName = 'TestTerritory', Territory2ModelId=terrModel.Id, Name='TestTerritory',Territory2TypeId=terriType[0].Id,Region__c='',Segment__c='',Sub_Region__c='',Theater__c='');
        insert objTerr;
        
        ObjectTerritory2Association objObjectTerritory2Association = new ObjectTerritory2Association(ObjectId = account.Id,Territory2Id =objTerr.Id,AssociationCause='Territory2Manual');
        insert objObjectTerritory2Association;
        
        Test.startTest();
        
        OppTerrAssignDefaultLogicFilter filter = new OppTerrAssignDefaultLogicFilter();
        filter.getOpportunityTerritory2Assignments(opplst);
        Map<Id, Id> resultMap = filter.getOpportunityTerritory2Assignments(new List<Id> {opp.Id});
        filter.getAccountMaxPriorityTerritory(terrModel.id, accountIds);
        filter.getActiveModelId();
        
        Test.stopTest();
        
    }        
}

}