Bulk Updating Records in Apex from List?

Question

I am writing code that calls an API to get external client info. I'm at the point where I have it working but I am wondering if there is a more efficient way to save the data to the Account object. Right now I am iterating through the list I have and updating each account but I am hitting governor limits pretty easily:

     List<ParseAdminResponse> acctList = ParseAdminResponse.parse(response.getBody());
        for(Integer i = 0; i < acctList.size(); i++){
         if(acctList[i].Success = true){
          acctId = acctList[i].SfAccountId;
          version = acctList[i].ClientVersion;
          Date todaysDate = system.today();
          // Query for the account
            Account queriedAccount = [SELECT Version__c 
                          FROM Account 
                          WHERE id = :acctId];

          // Update the account's version
          queriedAccount.Version__c = version;
          queriedAccount.Last_Admin_Check__c = todaysDate;
          update queriedAccount;

          } else{
          system.debug(acctList[i].ErrorMessage); 
          }
        }

Is there a better way than saving the results I get one at a time?

Answer 1

You don't need to query the records first, unless you needed to lock them. You can just construct the records in memory and update:

Date todaysDate = system.today();
Map<Id, Account> accounts = new Map<Id, Account>();
for(ParseAdminResponse par: acctList) {
    if(par.Success) {
        accounts.put(par.SfAccountId, new Account(Id=par.SfAccountId, Version__c=par.ClientVersion, Last_Admin_Check__c=todaysDate));
    }
}
update accounts.values();

If you really wanted to lock the records first:

Date todaysDate = system.today();
Map<Id, Account> accounts = new Map<Id, Account>();
for(ParseAdminResponse par: acctList) {
    if(par.Success) {
        accounts.put(par.SfAccountId, new Account(Id=par.SfAccountId, Version__c=par.ClientVersion, Last_Admin_Check__c=todaysDate));
    }
}
Account[] locks = [SELECT Id FROM Account WHERE Id = :accounts.keySet() FOR UPDATE];
update accounts.values();