Populating a dropdown list with values from a Data Extension in ampscript

Question

I am new to SFMC. Trying to populate the dropdown list from a DE through Ampscript.

I am trying this code. Any help is appreciated.

Data DE Name: testcompname

Column Name: company_name

Sending DE Name: test_seed

Column Names: email_id, org_name

%%[ 
var @compname, @compname_rows
SET @compname_rows = lookupRows("testcompname", "compname", @company_name)
SET @compname = Lookup(@testcompname, "key", "company_name")

%%[ if @compname_rows > 0 then ]%%

    <select name="">
        <option value="">Select</option>

    %%[ for @i = 1 to @compname_rows do ]%%

        <option value="%%=v(@compname)(@i)=%%">%%=v(@compname)(@i)=%%</option>

    %%[ next @i ]%%  

    </select>

%%[ else ]%%

        <br>Options not found 
%%[ endif ]%%
]%%

Answer 1

I'd suggest looking over some the lookup examples:

• http://ampscript.guide/book/lookuprows
• https://sprignaturemoves.com/ampscript-lookup-examples/

If I were to output an option list of companies for a specific region, I'd approach it like this:

%%[

var @compname_rows, @compname_row, @rowCount, @company_region, @i

set @company_region = "Central"
set @compname_rows = LookupRows("Companies", "region", @company_region)
set @rowCount = rowcount(@compname_rows)

output(concat("company_region: ", @company_region))

if @rowCount > 0 then 

    for @i = 1 to @rowCount do

        if @i == 1 then
          output(concat('<select name=""><option value="">Select</option>'))
        endif

        var @compname
        set @compname_row = row(@compname_rows, @i)
        set @compname = field(@compname_row,"emailAddress")

        output(concat('<option value="', @compname, '">', @compname, '</option>'))

        if @i == @rowCount then
          output(concat('</select>'))
        endif

    next @i 

else

 output(concat("<br>companies not found"))

endif 

]%%

Setting your lookup key can vary based on how the input is getting to where the AMPscript is located.

• for an email: set @company_region = AttributeValue("region")
• for a landing/cloud page: set @company_region = QueryParameter("region")

Reference

• AttributeValue
• QueryParameter