How do you perform JSON parsing in Apex scripting? [duplicate]

Question

I obtained some JSON output from a REST response and I want to parse that directly in my Apex script to either run if-tests or determine which JSON key contains information to run further actions. Salesforce doesn't seem to have good documentation here on how to do it, but I've seen references to a JSON2Apex module that can perform some of what I need. How can I learn how to properly parse JSON text responses to run follow-up actions? Is everything done by making calls to nextToken() or getCurrentToken() down the line until you find what you need?

Answer 1

There is a single page in the documentation, JSON Support, that has links to all of the various techniques you can use for serializing and deserializing JSON.

JSONParser is the the most involved method, because you're responsible for handling all the tokens correctly. It's much easier to use either of the automatic methods instead, JSON.deserialize and JSON.deserializeUntyped.

For example, you might do this:

Object base = JSON.deserializeUntyped(res.getBody());
if(base instanceOf List<Object>) {
  // Go through the list looking for a value
} else if(base instanceOf Map<String, Object>) {
  // Check the keys to see if it is present
}

You can do this recursively, if you desire:

Object findToken(Object struct, String key) {
  if(struct instanceOf List<Object>) {
    List<Object> values = (List<Object>)struct;
    for(Object value: values) {
      Object returnValue = findToken(value, key);
      if(returnValue != null) {
        return returnValue;
      }
    }
    return null;
  }
  if(struct instanceOf Map<String, Object>) {
    Map<String, Object> values = (Map<String, Object>)struct;
    return values.get(key);
  }
  return null;
}

I wrote a post a few years ago about an XmlToJSON parser that you might find relevant; instead of parsing JSON, it parses XML, but the principles of navigating through a complicated, recursive structure still apply. You can also find other stuff posted on the Internet; lots of people have written code to parse arbitrary (and no-so-arbitrary) JSON.

As you've noted, there's also JSON2Apex, which gives you a class to deserialize to. Doing this is probably the best way to do it, assuming you can get a sample of the JSON you're getting back, and it's some fairly standard JSON (I've seen really complicated that JSON2Apex can't handle, so fair warning...).

You might want to start with the documentation, though, in the end, because the information is there, it just happens to not be all on one page.