Apex Trigger not Firing on Mass Update

Question

After many attempts on my part, I'm hoping someone is able to help me out with this :)

Background and Desired Result:

I have a seemingly straightforward Apex Trigger that fires as Contacts are inserted, updated, etc...

I would like this trigger to simply update a single field on the Account that the Contact is tied to.

The Issue:

The trigger works as expected when Contacts are created or edited manually through the SFDC interface. However, the trigger does not appear to fire when thousands of contacts are updated in mass (i.e. via the Import Wizard).

I have included my code below. Any help would be greatly appreciated!

My Apex Code:

Trigger setNTCOnAccountViaContact on Contact (after INSERT, after UPDATE) {

Set<ID> setAccountIDs = new Set<ID>();
for (Contact c : Trigger.new) {
    setAccountIDs.add(c.AccountID);
}

String accountID = null;
for (String setElement : setAccountIDs) {
    accountID = setElement;
    break;
}

List<Contact> nextTargetContactObject = [SELECT Id FROM Contact
                                    WHERE Target_Contact__c = TRUE AND
                                    Account.Id = :accountID
                                    ORDER BY Target_Contact_Order__c ASC
                                    LIMIT 1];

List<Account> accounts = [SELECT Id FROM Account WHERE Id = :accountID];                    

if (nextTargetContactObject.size() == 1) {
    for (Account account : accounts) {
        account.Next_Target_Contact_ID__c = nextTargetContactObject[0].Id;
    }
} else {
    for (Account account : accounts) {
        account.Next_Target_Contact_ID__c = NULL;
    }
}
update accounts;                                        

}

Answer 1

You'll want to read Best Practice: Bulkify Your Code. Your code essentially only works on the first contact in each batch of 200 records processed, because despite all the gyrations your code goes through, it really only works on one record.

A more appropriate trigger would look like the following:

trigger setNTConAccountViaContact on Contact (after INSERT, after UPDATE) {
    // Data we'll use in this trigger
    Set<Id> accountIds = new Set<Id>();
    Account[] updateAccounts = new Account[0];
    Map<Id, String> error = new Map<Id, String>();

    // Find all account Id values
    for(Contact record: Trigger.new) {
        accountIds.add(record.AccountId);
    }
    // Ignore AccountId = null
    accountIds.remove(null);

    // Abort early if no accounts to process
    if(accountIds.isEmpty()) {
        return;
    }
    // Query accounts that need to be updated
    for(Account record: [
            SELECT (SELECT Id FROM Contacts
                    WHERE Target_Contact__c = TRUE
                    ORDER BY Target_Contact_Order__c
                    LIMIT 1)
            FROM Account WHERE Id = :accountIds]) {
        updateAccounts.add(
            new Account(
                Id=record.Id, 
                Next_Target_Contact_ID__c=
                    (record.Contacts.isEmpty()?null:record.Contacts[0].Id)));
    }

    // Attempt to update
    Database.SaveResult[] results = Database.update(updateAccounts, false);

    // NOTE: this is optional; skip if you don't want to report errors.

    // Process errors
    for(Integer index = 0, size = results.size(); index < size; index++) {
        if(!results[index].isSuccess()) {
            error.put(updateAccounts[index].Id, results[index].getErrors()[0].getMessage());
        }
    }
    // Report errors to parent context
    for(Contact record: Trigger.new) {
        if(error.containsKey(record.AccountId)) {
            record.addError('Failed to update account record: '+error.get(record.AccountId));
        }
    }
}