How to implement my de-dupe code into batch apex?

Question

My anonymous de-dupe Account apex code runs successfully until it hits a DML limit on the merge execution. I do not want to reduce the size of my query. How do I implement this in batch apex so that it is aware of governor limits?

In particular, I want it to run in batches of appropriate size so that it can complete without giving me "too many DML statements".

// Assumption is accounts exist with dupe DunsNumber

List<Account> allMasters = [SELECT Id, DunsNumber FROM Account WHERE CreatedBy.LastName!='Smith' AND DunsNumber!=null];
List<Account> allPotentialDupes = [SELECT Id, DunsNumber FROM Account WHERE CreatedBy.LastName='Smith' AND DunsNumber!=null];

Map<Account, List<Account>> mastersDupes = new Map<Account, List<Account>>();

for (Account master : allMasters){
    List<Account> mSDupes = new List<Account>();
    for (Account dupe : allPotentialDupes){
        if(master.DunsNumber == dupe.DunsNumber){ //dupe account identified so add it to the mastersDupes list
            mSDupes.add(dupe);
        }
    }

    mastersDupes.put(master, mSDupes);

}

for (Account masterAcct : mastersDupes.keySet()) { //for every key in mastersDupes
    List<Account> keysDupeList = new List<Account>();
    keysDupeList.addAll(mastersDupes.values()[0]);
    for (Account mergeAcct : keysDupeList) //mergeAcct with the masterAcct
    {
        try {
        merge masterAcct mergeAcct;
        } catch (DmlException e) {
        // Process exception
        System.debug('An unexpected error has occurred: ' + e.getMessage()); 
        }
    }

}

Answer 1

If you're just using an anonymous script and trying to knock this task out quickly, you can add a limits check and just bail once you've performed the maximum number of DML Statements.

for (...)
{
    if (Limits.getLimitDmlStatements() > Limits.getDmlStatements())
    {
        merge ...
    }
    else
    {
        break;
    }
}

Answer 2

You can reduce your DML statements by up to half by using the alternative format for merge, which takes a single record and two related records:

Account master = dups.remove(0);
Account[] children = new Account[0];
while(!dups.isEmpty()) {
    while(!dups.isEmpty() && children.size() < 2) {
        children.add(dups.remove(0));
    }
    try {
        merge master children;
    } catch(DmlException e) {
        // Report an error
    }
    children.clear();
}

As for the first loop-within-a-loop, you could use a map for efficiency:

Map<String, Account[]> dupList = new Map<String, Account[]>();
for(Account record: allMasters) {
    if(!dupList.containsKey(record.DunsNumber)) {
        dupList.put(record.DunsNumber, new Account[0]);
    }
    dupList.get(record.DunsNumber).add(record);
}

As far as making it batchable? I wouldn't. Instead, use Queueable to continue as long as you have more work to do:

List<Account[]> accounts = dupList.values();
System.enqueueJob(this);

...

public void execute(Database.QueueableContext context) {
    doMergeLogic();
    if(!accounts.isEmpty()) {
        System.enqueueJob(this);
    }
}

Queueable is a lot more appropriate than batchable in this case, because you don't know how many DML statements you need, and batchable's size can't be dynamically changed midway.