Trouble in using Business hours methods to compare business hours with specific number of hours in apex trigger

Question

I'm trying to compare number of business hours with number of hours (bh<48) I have gone through few methods and tried the below method to get number of hours(difference between startdate and enddate :

diff(BusinessHours.id, startdate, Datetime.now())<48)

But I'm constantly getting the same error for all the methods : "Method does not exist or incorrect signature: [BusinessHours].diff(Schema.SObjectField, Datetime, Datetime)"

I dont understand this error as usage of methods are referred here

https://developer.salesforce.com/docs/atlas.en-us.apexcode.meta/apexcode/apex_classes_businesshours.htm

Any suggestions are highly appreciated! TIA

Answer 1

You are going to have to do something like this first: (from your link)

BusinessHours bh = [SELECT Id FROM BusinessHours WHERE IsDefault=true];

Then use that id as the first parameter in the method:

diff(bh.id, startdate, Datetime.now())<48)

You were getting an error message because you were using the name of the type of parameter that you needed to put into the function instead of using a value of that type.

---

I got this to run:

BusinessHours bh = [SELECT Id FROM BusinessHours WHERE IsDefault=true];
Datetime startdate = Datetime.newInstance(2013, 5, 28, 1, 6, 8);
long l = BusinessHours.diff(bh.id,startdate,system.now());
system.debug(l);  

---

I this also worked for me:

BusinessHours bh = [SELECT Id FROM BusinessHours WHERE IsDefault=true];
Case c = [SELECT ClosedDate FROM Case WHERE ClosedDate != NULL LIMIT 1];

DateTime startdate = c.ClosedDate;
DateTime systemnow = system.now();

long startl = startdate.getTime();
long nowl   = systemnow.getTime();
long diffl  = BusinessHours.diff(bh.id,startdate,systemnow);

system.debug('startl: ' + startl);
system.debug('nowl: '   + nowl);
system.debug('nowl - startl: ' + (nowl - startl));
system.debug('diffl: '  + diffl);

system.assertEquals(nowl-startl,diffl);

---

This also works:

Trigger Test_Business_hours_Trigger on EmailMessage (after insert) {
    BusinessHours bh = [SELECT Id FROM BusinessHours WHERE IsDefault=true];
    list<Id> RelatedCaseIds = new list<Id>();
    for(EmailMessage em : Trigger.New){
        RelatedCaseIds.add(em.ParentId);
    }
    list<Case> CasesToUpdate = new list<Case>();
    for(Case c : [SELECT Id, ClosedDate FROM Case WHERE Id IN :RelatedCaseIds AND ClosedDate != NULL]){
        if(BusinessHours.diff(bh.Id,c.ClosedDate,system.now()) < 172800000){
            c.Status = 'Working';
            CasesToUpdate.add(c);
        }
    }
    update CasesToUpdate;
}