The primary issue is that if a parameter isn't provided, it will be null, which will crash your if statements:

    if (!applicantName.equals('')) // System.NullPointerException can happen here.

Instead, use the safer String.isNotBlank:

    if(String.isNotBlank(applicantName)) // Safe from System.NullPointerException

Secondly, your query is initialized in two different places, which increases maintenance and increases the odds of an error. Instead, build the query in runQuery.

public void runQuery() {
    soql = 'Select Id,Name,Existing_Employee__c,ApplicantStreet__c,ApplicantCounty__c,ApplicantState__r.Name,ApplicantZip_Code__c from Applicant__c';
    String applicantName = Apexpages.currentPage().getParameters().get('applicantName');
    String applicantcounty = Apexpages.currentPage().getParameters().get('applicantcounty');
    String applicantstate = Apexpages.currentPage().getParameters().get('applicantstate');
    String applicantzipcode = Apexpages.currentPage().getParameters().get('applicantzipcode');
    String[] whereClause = new String[0];
    
    soql = 'Select Id,Name,Existing_Employee__c,ApplicantStreet__c,ApplicantCounty__c,ApplicantState__r.Name,ApplicantZip_Code__c from Applicant__c';
    if (String.isNotBlank(applicantName)) {
        whereClause.add('Name LIKE :applicantName');
        applicantName += '%';
    }
    if (String.isNotBlank(applicantCounty)) {
        whereClause.add('ApplicantCounty__c LIKE :applicantCounty');
        applicantCounty += '%';
    }
    if (String.isNotBlank(applicantstate)) {
        whereClause.add('ApplicantState__r.Name LIKE :applicantstate');
        applicantstate += '%';
    }
    if (String.isNotBlank(applicantzipcode)) {
        whereClause.add('ApplicantZip_Code__c LIKE :applicantzipcode');
        applicantzipcode += '%';
    }
    if(!whereClause.isEmpty()) {
        soql += ' WHERE '+String.join(whereClause,' AND ');
    }
    Applicants  = Database.query(soql);
}