Take the 2-minute tour ×
Salesforce Stack Exchange is a question and answer site for Salesforce administrators, implementation experts, developers and anybody in-between. It's 100% free, no registration required.

In Apex, how can you calculate the number of days between two dates excluding any days that fall on the weekend?

This would be similar to the existing Date.daysBetween() method.

There is a similar question that deals with the same issue in formula fields - Calculating Turnaround Time in Date Fields.

The question How Can I Tell the Day of the Week of a Date? provides methods for finding the day of the week in Apex.

share|improve this question
add comment

3 Answers

up vote 8 down vote accepted

So I wrote some code to handle this recently. It is completely configurable, and as efficient as can be.

The most important thing is to set the isWorkingDay array with the right flags (index 0 is Monday) and to make sure workingDaysInWeek matches the number of true flags in the array. After that the method will return a value for you.

//array of seven boolean indicating working days, Monday is index 0
private static final List<Boolean> isWorkingDay;
//count of the number of working days in the array
private static final Integer workingDaysInWeek;
static {
    //my real implementation uses the Salesforce BusinessHours Object to populate this array
    isWorkingDay = new List<Boolean> { true, true, true, true, true, false, false };
    //You will have real problems if this number does not match the number of true flags in the array
    workingDaysInWeek = 5;
}

private static final Date monday = Date.newInstance(1900, 1, 3);
private static Integer getDayOfWeek(Date value) {
    return Math.mod(monday.daysBetween(value), 7);
}

public static Integer getWorkingDays(Date startDate, Date endDate) {
    //save some calculations when the number of working days is 0
    if(workingDaysInWeek == 0 || startDate == null || endDate == null) {
        return 0;
    } else {
        Integer difference = startDate.daysBetween(endDate);
        if(difference == 0) {
            //If the 2 dates are the same day check if the day is a working day or not
            return isWorkingDay[getDayOfWeek(startDate)] ? 1 : 0;
        } else if(workingDaysInWeek == 7) {
            //when every day is a working day return the difference
            return difference;
        } else {
            //The guts of the solution
            Integer wholeWeeks = Math.floor(difference / 7).intValue();
            Integer workingDays = wholeWeeks * workingDaysInWeek;
            Integer dayOfWeek = getDayOfWeek(endDate);
            for(Integer remainder = Math.mod(difference, 7); remainder >= 0; remainder--) {
                if(isWorkingDay[remainder]) {
                    workingDays++;
                }
                dayOfWeek--;
                if(dayOfWeek < 0) {
                    dayOfWeek = 6;
                }
            }
            return workingDays;
        }
    }
}
share|improve this answer
    
Nice, this seems a lot more flexible, especially when combined with the BusinessHours. –  Daniel Ballinger Dec 12 '12 at 21:24
    
This is truly helpful.. I was looking for something along these lines (plus learned a couple things just checking out the code as well). Thanks. –  AMM Dec 12 '12 at 21:48
add comment

Here is one possibile solution. It is a bit brute force as it examines every single day between the two inputs. So the further the dates are apart the more expensive it is to compute.

Also, it assumes that the startDate is less than the endDate to start with. So it won't return negative values like Date.daysBetween() can.

public static Integer daysBetweenExcludingWeekends(Datetime startDate, Datetime endDate) {
    Integer i = 0;

    while (startDate < endDate) {
        if (startDate.format('EEE') != 'Sat' && startDate.format('EEE') != 'Sun') {
            i = i + 1;
        }
        startDate = startDate.addDays(1);
    }

    return i;
}

Alternative attempt using daysBetween (not tested yet). Based on a C# example by Jon Egerton.

public static Integer daysBetweenExcludingWeekends(Datetime startDate, Datetime endDate) {
    //Work out days in range
    Integer days = startDate.date().daysBetween(endDate.date());

    //Remove most weekends by removing 2 in 7 days (rounded down)
    days -= ((integer)Math.floor((days / 7)) * 2);

    if (startDate.format('EEE') != 'Sat') {
        days -= 1;
    } else if (startDate.format('EEE') != 'Sun') {
        days -= 2;
    }

    return days;
}
share|improve this answer
    
You should be able to determine the start and end day, and then based on the number of days between them just rip out 2 out of every 7 (which some extra consideration being given based on there being a partial final week). –  Michael Welburn Dec 12 '12 at 20:51
    
@MichaelWelburn agreed. It will be possible to come up with a more flexible solution using the existing daysBetween() method and some division/modulo calculations. –  Daniel Ballinger Dec 12 '12 at 20:58
    
@MichaelWelburn I wrote something to solve this exact problem a few weeks ago, I've just posted it as an answer –  Daniel Blackhall Dec 12 '12 at 21:19
add comment

You can use the business hours class from Salesforce to get this done easiy in apex.

You would first query for the business hours set in your system and then use the

Businesshours.diff(starttime,endtime) to get the time difference in milliseconds.

Reference: http://www.salesforce.com/us/developer/docs/apexcode/Content/apex_classes_businesshours.htm

share|improve this answer
add comment

Your Answer

 
discard

By posting your answer, you agree to the privacy policy and terms of service.

Not the answer you're looking for? Browse other questions tagged or ask your own question.